Hello,

Is there a reliable way to align framed graphics in a row, in such a way
that both the top and bottom of the frame are at the same level?

Here is an example:

GraphicsRow[
  {
   LogLogPlot[1 + Sin[x], {x, 1, 100}, Axes -> False, Frame -> True,
    FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5],
   Plot[Sinc[x], {x, -5, 5}, Axes -> False, Frame -> True,
    FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5]
   }]

Note how the second graphic is taller than the first one.  I would like
the frames to be properly aligned, for aesthetic reasons.  All my
graphics have (different) frame labels, and their aspect ratio is fixed.

The two plots look different because of the different sizes of the material
outside of the frame. In this case it is the different widths of the
vertical tick labels.

The way to fix this is to explicitly specify the space allotted for the
outside-the-frame items using the ImagePadding option. Then it will be the
same for both plots. You must specify the ImagePadding to be large enough to
accommodate all the material in all of the plots.

GraphicsRow[{LogLogPlot[1 + Sin[x], {x, 1, 100}, Axes -> False,
   Frame -> True, FrameLabel -> {"horizontal", "vertical"},
   AspectRatio -> 4/5,
   ImagePadding -> {{50, 5}, {40, 5}}],
  Plot[Sinc[x], {x, -5, 5}, Axes -> False, Frame -> True,
   FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5,
   ImagePadding -> {{50, 5}, {40, 5}}]},
 ImageSize -> 600]

David Park
djmp...@comcast.net
http://home.comcast.net/~djmpark/

From: Szabolcs Horv=E1t [mailto:szhor...@gmail.com]

Hello,

Is there a reliable way to align framed graphics in a row, in such a way
that both the top and bottom of the frame are at the same level?

Here is an example:

GraphicsRow[
  {
   LogLogPlot[1 + Sin[x], {x, 1, 100}, Axes -> False, Frame -> True,
    FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5],
   Plot[Sinc[x], {x, -5, 5}, Axes -> False, Frame -> True,
    FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5]
   }]

Note how the second graphic is taller than the first one.  I would like
the frames to be properly aligned, for aesthetic reasons.  All my
graphics have (different) frame labels, and their aspect ratio is fixed.

2009/11/5 Szabolcs Horv=E1t <szhor...@gmail.com>:

Just set an explicit value for ImagePadding.

GraphicsRow[{LogLogPlot[1 + Sin[x],
   {x, 1, 100}, Axes -> False, Frame -> True,
   FrameLabel -> {"horizontal", "vertical"},
   AspectRatio -> 4/5,
   ImagePadding -> {{50, 5}, {40, 5}}],
  Plot[Sinc[x], {x, -5, 5},
   Axes -> False, Frame -> True,
   FrameLabel -> {"horizontal", "vertical"},
   AspectRatio -> 4/5,
   ImagePadding -> {{50, 5}, {40, 5}}]}]

Mark McClure

Szabolcs Horv=E1t schrieb:

I think that the difference in frame dimensions is due to different
settings of ImagePadding. You can achieve what you want with setting
ImagePadding to the same value for all your plots:

padding = 20;
GraphicsRow[{LogLogPlot[1 + Sin[x], {x, 1, 100}, Axes -> False,
   Frame -> True, FrameLabel -> {"horizontal", "vertical"},
   AspectRatio -> 4/5, ImagePadding -> padding],
  Plot[Sinc[x], {x, -5, 5}, Axes -> False, Frame -> True,
   FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5,
   ImagePadding -> padding]}]

It needs some iterations to find a value that works for all plots.
Unfortunatley finding the largest ImagePadding values with
AbsoluteOptions and use that automatically seems to not work since it
will return ImagePadding -> All which is not much help...

hth,

albert

On 2009.11.05. 10:20, Szabolcs Horv=E1t wrote:

I think I found a solution:

The key is the ImagePadding option.  The above example could be modified
like this:

GraphicsRow[
  Show[#, ImagePadding -> {{All, All}, {All, 5}}] & /@ {LogLogPlot[
     1 + Sin[x], {x, 1, 100}, Axes -> False, Frame -> True,
     FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5],
    Plot[Sinc[x], {x, -5, 5}, Axes -> False, Frame -> True,
     FrameLabel -> {"horizontal", "vertical"}, AspectRatio -> 4/5]}]

Each graphic needs to have the same top and bottom ImagePadding.  The
automatically computed values at the bottom are the same in this
particular case.  The top value was set to 5 manually.  If I understand
it correctly, the value given to ImagePadding is to be understood in
printer's points (but it accepts Scaled[] values as well).